\start83\
\comment=Programm Dateidatum 08/26/01, 15:17
\name=CHKHUNT
\file=C:\PROGRA~1\TI-GRA~1\CHKHUNT.TXT
ClrHome
Output(4,3,"CHICKEN HUNT
Output(5,8,"By\1\HvdB
Output(5,10," 
Lbl IT
randInt(1,8\->\A
randInt(1,8\->\B
If A=4 or A=5 or B=4 or B=5 or A=B
Goto IT
getKey
If Ans\!=\0
Goto M
For(\theta\,14,1,\(-)\1
Output(A,\theta\,"<8X 
For(W,1,50
End
End
Output(A,1,"   
getKey
If Ans\!=\0
Goto M
For(\theta\,1,13
Output(B,\theta\," X8>
For(W,1,50
End
End
Output(B,14,"   
Goto IT
Lbl M
ClrHome
Disp "
Disp "++CHICKEN HUNT++
Disp "1>NEW GAME
Disp "2>HIGHSCORE
Disp "3>INSTRUCTIONS
Disp "4>QUIT
getKey
While Ans=0
getKey
End
If Ans=92
Goto NG
If Ans=93
Goto HS
If Ans=94
Goto I
If Ans=82
Goto Q
Goto M
Lbl NG
0\->\C
200\->\L
2\->\T
8\->\X
4\->\Y
0\->\P
6\->\M
ClrHome
Output(4,4,"GET READY
For(\theta\,1,300
End
Lbl SL
ClrList L\5\
ClrList L\6\
T\->\dim(L\5\
T\->\dim(L\6\
For(\theta\,1,T
randInt(1,7\->\L\5\(\theta\
randInt(4,13\->\L\6\(\theta\
End
ClrHome
Output(8,7,"-T\i\max(
Output(8,11,"e: 
For(\theta\,1,M
Output(8,\theta\,"*
End
Lbl G
0\->\S
While S=0
Output(8,14,L
If L<100
Output(8,16," 
If L<10
Output(8,15," 
If L=0
Goto X
L-1\->\L
getKey\->\K
If Ans=22 and M=0
Then
6\->\M
Output(8,1,"******
End
If Ans=23
1\->\S
If K=21 and M>0
Then
Output(8,M," 
M-1\->\M
For(Z,1,T
For(\theta\,0,2
If X=L\6\(Z)+\theta\ and Y=L\5\(Z
Then
P+2\->\P
If 0=fPart(P/10
2\->\S
Output(L\5\(Z),L\6\(Z),"    
1\->\L\6\(Z
randInt(1,7\->\L\5\(Z
End
End
End
End
C+1\->\C
If C=2
Then
0\->\C
For(\theta\,1,T
Output(L\5\(\theta\),L\6\(\theta\)," X8>
1+L\6\(\theta\\->\L\6\(\theta\
If 14=L\6\(\theta\
Then
P-1\->\P
Output(L\5\(\theta\),14,"   
1\->\L\6\(\theta\
End
End
End
Output(Y,X," 
X+(K=26 and X<16)-(K=24 and X>1\->\X
Y+(K=34 and Y<7)-(K=25 and Y>1\->\Y
Output(Y,X,"+
End
If 1=S
Menu("    >PAUSED<    ","RESUME",G,"EXIT",Q
T+1\->\T
Goto SL
Lbl X
ClrHome
Output(4,4,"GAME OVER!
Output(5,2,"YOUR SCORE:
Output(5,14,P
Pause 
ClrHome
1\->\dim(\L\CHKH
0\->\F
If 0=\L\CHKH(1
Then
Output(4,3,"THIS IS THE
Output(5,3,"FIRST RECORD
P\->\\L\CHKH(1
1\->\F
End
If P\<=\\L\CHKH(1) and 0=F
Then
Output(4,2,"THE HIGHSCORE
Output(5,3,"IS STILL
Output(5,12,\L\CHKH(1
End
If P>\L\CHKH(1
Then
Output(4,2,"YOU BROKE THE
Output(5,2,"HIGHSCORE!
P\->\\L\CHKH(1
End
Pause 
Goto M
Lbl HS
ClrHome
Disp "
Disp "  -HIGHSCORE-
Disp "CURRENT HIGH-
Disp "SCORE:
1\->\dim(\L\CHKH
If 0=\L\CHKH(1
Then
Output(4,8,"(NONE)
Else
Output(4,8,\L\CHKH(1
End
Disp "1>RESET
Disp "2>RETURN
getKey
While Ans=0
getKey
End
If Ans=92
Then
ClrHome
DelVar \L\CHKH
Output(4,4,"HIGHSCORE
Output(5,4,"RESETTED
Pause 
End
Goto M
Lbl I
ClrHome
Disp "THE GOAL OF THIS
Disp "GAME IS TO SHOOT
Disp "AS MANY CHICKENS
Disp "AS POSSIBLE
Disp "WITHIN THE TIME.
Disp "YOU GET 2 POINTS
Pause "FOR EACH CHICKEN
ClrHome
Disp "WHEN A CHICKEN
Disp "REACHES THE
Disp "OTHER SIDE OF
Disp "THE SCREEN
Disp "BEFORE YOU SHOOT
Disp "IT, YOU LOSE 1
Pause "POINT.
ClrHome
Disp " KEY CONTROLS:
Disp " -------------
Disp "CURSOR KEYS:
Disp "MOVE POINTER
Disp "2ND: SHOOT
Disp "MODE: RELOAD
Pause "DEL: PAUSE GAME
Goto M
Lbl Q
ClrList L\4\
ClrList L\5\
ClrList L\6\
ClrHome
Output(1,1,"
\stop83\

